Demo 11 of 14 in category OsgHelp
 |
# SlaveCameras.tcl
#
# Original C++ code by Peter Wraae Marino and Michael Bach Jensen.
# See www.osghelp.com for the original files.
#
# Modified for Tcl3D by Paul Obermeier 2010/03/20.
# See www.tcl3d.org for the Tcl3D extension.
package require tcl3d
if { ! [tcl3dHaveOsg] } {
tk_messageBox -icon error -type ok -title "Missing Tcl3D module" \
-message "Demo needs the tcl3dOSG module."
proc Cleanup {} {}
exit 1
return
}
# Font to be used in the Tk listbox.
set gDemo(listFont) {-family {Courier} -size 10}
# Window size.
set gDemo(winWidth) 640
set gDemo(winHeight) 480
# Determine the directory and filename of this script.
set gDemo(scriptFile) [info script]
set gDemo(scriptDir) [file dirname $gDemo(scriptFile)]
# Show errors occuring in the Togl callbacks.
proc bgerror { msg } {
puts "Error: $msg\n\n$::errorInfo"
tk_messageBox -icon error -type ok -message "Error: $msg\n\n$::errorInfo"
ExitProg
}
# Print info message into widget a the bottom of the window.
proc PrintInfo { msg } {
if { [winfo exists .fr.info] } {
.fr.info configure -text $msg
}
}
# Idle callback to redisplay the scene.
proc Animate {} {
.fr.toglwin postredisplay
set ::animateId [after idle Animate]
}
proc StartAnimation {} {
if { ! [info exists ::animateId] } {
Animate
}
}
proc StopAnimation {} {
if { [info exists ::animateId] } {
after cancel $::animateId
unset ::animateId
}
}
proc CreateCallback { toglwin } {
}
proc ReshapeCallback { toglwin { w -1 } { h -1 } } {
global gDemo
set w [$toglwin width]
set h [$toglwin height]
# Propagate resize event to embedded OSG window.
tcl3dOsgWindowResize $toglwin [tcl3dOsgGetOsgWin] $w $h
rCam setViewport 0 0 $w $h
set gDemo(winWidth) $w
set gDemo(winHeight) $h
}
proc DisplayCallback { toglwin } {
if { [viewer valid] } {
viewer frame
}
$toglwin swapbuffers
}
proc Cleanup {} {
uplevel #0 unset gDemo
viewer -delete
}
proc ExitProg {} {
exit
}
proc SaveOsgToFile {} {
global gDemo
set osgRoot [viewer getSceneData]
set outFile [format "%s.osgt" [file rootname $gDemo(scriptFile)]]
# Create a name on the file system, if running from within a Starpack.
set outFile [tcl3dGenExtName $outFile]
puts "Saving scenegraph to file $outFile"
if { ! [osgDB::writeNodeFile $osgRoot $outFile] } {
puts "Failed to write scenegraph to file $outFile"
}
}
proc CreateWidgets { osgwin } {
global gDemo
frame .fr
pack .fr -expand 1 -fill both
set toglwin .fr.toglwin
togl $toglwin -width $gDemo(winWidth) -height $gDemo(winHeight) \
-double true -depth true -alpha true \
-createcommand CreateCallback \
-reshapecommand ReshapeCallback \
-displaycommand DisplayCallback
listbox .fr.usage -font $gDemo(listFont) -height 3
label .fr.info
grid $toglwin -row 0 -column 0 -sticky news
grid .fr.usage -row 1 -column 0 -sticky news
grid .fr.info -row 2 -column 0 -sticky news
grid rowconfigure .fr 0 -weight 1
grid columnconfigure .fr 0 -weight 1
wm title . "Tcl3D demo: OsgHelp tutorial SlaveCameras"
wm protocol . WM_DELETE_WINDOW "ExitProg"
bind . <Key-Escape> "ExitProg"
bind . <Key-f> "SaveOsgToFile"
# Propagate key and mouse events to embedded OSG window.
bind . <KeyPress> "tcl3dOsgKeyPress $toglwin $osgwin %N"
tcl3dOsgAddTrackballBindings $toglwin $osgwin
.fr.usage insert end "Key-Escape Exit"
.fr.usage insert end "Key-f Save SceneGraph to file"
.fr.usage insert end "Mouse Trackball"
.fr.usage configure -state disabled
}
#
# Start of tutorial specific code.
#
proc CreateScene {} {
osg::Geode geode1
# create 4 evenly spaced cubes
geode1 addDrawable [osg::ShapeDrawable dr1 [osg::Box box1 [osg::Vec3 v1 2.0 2.0 0.0] 2.0]]
geode1 addDrawable [osg::ShapeDrawable dr2 [osg::Box box2 [osg::Vec3 v2 2.0 -2.0 0.0] 2.0]]
geode1 addDrawable [osg::ShapeDrawable dr3 [osg::Box box3 [osg::Vec3 v3 -2.0 2.0 0.0] 2.0]]
geode1 addDrawable [osg::ShapeDrawable dr4 [osg::Box box4 [osg::Vec3 v4 -2.0 -2.0 0.0] 2.0]]
return geode1
}
proc CreateScene2 {} {
# create big cube
osg::Geode geode2
geode2 addDrawable [osg::ShapeDrawable dr5 [osg::Box box5 [osg::Vec3 v5 0.0 0.0 0.0] 4.0]]
# make it red so we can easily identify the cube
osg::Material mat
mat setDiffuse $::osg::Material_FRONT [osg::Vec4 diffuse 1 0 0 1]
[geode2 getOrCreateStateSet] setAttribute mat $::osg::StateAttribute_OVERRIDE
return geode2
}
# We have the geometry ready. Now create the viewer and the Tk widgets.
osgViewer::ViewerRef viewer [osgViewer::Viewer]
if { $argc >= 1 && [lindex $argv 0] eq "-viewer" } {
# Only use the standard OSG viewer window without any Tk widgets.
viewer setUpViewInWindow 50 50 500 400
} else {
# Use the OSG viewer inside a Togl widget.
set osgwin [viewer setUpViewerAsEmbeddedInWindow 50 50 500 400]
tcl3dOsgSetOsgWin $osgwin
}
# set the scene-graph data the viewer will render
viewer setSceneData [CreateScene]
viewer setCameraManipulator [osgGA::TrackballManipulator]
# slave camera
osg::Camera rCam
set cam [viewer getCamera]
set context [osg::Camera_getGraphicsContext $cam]
rCam setGraphicsContext $context
rCam setViewport 0 0 500 400
viewer addSlave rCam false
rCam setInheritanceMask [expr [rCam getInheritanceMask] & ~$::osg::CullSettings_CLEAR_COLOR]
rCam setClearMask $::GL_DEPTH_BUFFER_BIT
rCam addChild [CreateScene2]
if { $argc >= 1 && [lindex $argv 0] eq "-viewer" } {
viewer run
exit 0
}
viewer realize
CreateWidgets $osgwin
PrintInfo [tcl3dOsgGetInfoString]
if { [file tail [info script]] eq [file tail $::argv0] } {
# If started directly from tclsh or wish, then start animation.
update
StartAnimation
}
|
