# bezcurve.tcl
#
# An example of the OpenGL red book modified to work with Tcl3D.
# The original C sources are Copyright (c) 1993-2003, Silicon Graphics, Inc.
# The Tcl3D sources are Copyright (c) 2005-2026, Paul Obermeier.
# See file LICENSE for complete license information.
#
# This program uses evaluators to draw a Bezier curve.

package require tcl3d

set ctrlpoints {
    {-4.0 -4.0 0.0} {-2.0 4.0 0.0} 
    { 2.0 -4.0 0.0} { 4.0 4.0 0.0}
}

# Font to be used in the Tk listbox.
set listFont {-family {Courier} -size 10}

# Show errors occuring in the Togl callbacks.
proc bgerror { msg } {
    tk_messageBox -icon error -type ok -message "Error: $msg\n\n$::errorInfo"
    exit
}

# Print info message into widget a the bottom of the window.
proc PrintInfo { msg } {
    if { [winfo exists .fr.info] } {
        .fr.info configure -text $msg
    }
}

proc CreateCallback { toglwin } {
    glClearColor 0.0 0.0 0.0 0.0
    glShadeModel GL_FLAT
    glMap1f GL_MAP1_VERTEX_3 0.0 1.0 3 4 [join $::ctrlpoints]
    glEnable GL_MAP1_VERTEX_3
}

proc DisplayCallback { toglwin } {
    glClear GL_COLOR_BUFFER_BIT

    # Viewport command is not really needed, but has been inserted for
    # Mac OSX. Presentation framework (Tk) does not send a reshape event,
    # when switching from one demo to another.
    glViewport 0 0 [$toglwin width] [$toglwin height]

    glColor3f 1.0 1.0 1.0
    glBegin GL_LINE_STRIP
    for { set i 0 } { $i <= 30 } { incr i } {
        glEvalCoord1f [expr double ($i)/30.0]
    }
    glEnd
    # The following code displays the control points as dots.
    glPointSize 5.0
    glColor3f 1.0 1.0 0.0
    glBegin GL_POINTS
    for { set i 0 } { $i < 4 } { incr i } {
        glVertex3fv [lindex $::ctrlpoints $i]
    }
    glEnd
    glFlush
    $toglwin swapbuffers
}

proc ReshapeCallback { toglwin { w -1 } { h -1 } } {
    set w [$toglwin width]
    set h [$toglwin height]

    glViewport 0 0 $w $h
    glMatrixMode GL_PROJECTION
    glLoadIdentity
    if { $w <= $h } {
       glOrtho -5.0 5.0 \
                [expr -5.0*double($h)/double($w)] \
                [expr 5.0*double($h)/double($w)] \
                -5.0 5.0
    } else {
        glOrtho [expr -5.0*double($w)/double($h)] \
                [expr 5.0*double($w)/double($h)] \
                -5.0 5.0 -5.0 5.0
    }
   glMatrixMode GL_MODELVIEW
   glLoadIdentity
}

frame .fr
pack .fr -expand 1 -fill both
togl .fr.toglwin -width 500 -height 500 -double true \
                 -createcommand CreateCallback \
                 -reshapecommand ReshapeCallback \
                 -displaycommand DisplayCallback 
listbox .fr.usage -font $::listFont -height 1
label   .fr.info
grid .fr.toglwin -row 0 -column 0 -sticky news
grid .fr.usage   -row 1 -column 0 -sticky news
grid .fr.info    -row 2 -column 0 -sticky news
grid rowconfigure .fr 0 -weight 1
grid columnconfigure .fr 0 -weight 1
wm title . "Tcl3D demo: OpenGL Red Book example bezcurve"

bind . <Key-Escape> "exit"

.fr.usage insert end "Key-Escape Exit"
.fr.usage configure -state disabled

PrintInfo [tcl3dOglGetInfoString]
