# model.tcl
#
# An example of the OpenGL red book modified to work with Tcl3D.
# The original C sources are Copyright (c) 1993-2003, Silicon Graphics, Inc.
# The Tcl3D sources are Copyright (c) 2005-2022, Paul Obermeier.
# See file LICENSE for complete license information.
#
# This program demonstrates modeling transformations

package require tcl3d

# Font to be used in the Tk listbox.
set listFont {-family {Courier} -size 10}

# Show errors occuring in the Togl callbacks.
proc bgerror { msg } {
    tk_messageBox -icon error -type ok -message "Error: $msg\n\n$::errorInfo"
    exit
}

# Print info message into widget a the bottom of the window.
proc PrintInfo { msg } {
    if { [winfo exists .fr.info] } {
        .fr.info configure -text $msg
    }
}

proc CreateCallback { toglwin } {
    glClearColor 0.0 0.0 0.0 0.0
    glShadeModel GL_FLAT
}

proc draw_triangle {} {
    glBegin GL_LINE_LOOP
    glVertex2f 0.0 25.0
    glVertex2f 25.0 -25.0
    glVertex2f -25.0 -25.0
    glEnd
}

proc DisplayCallback { toglwin } {
    glClear GL_COLOR_BUFFER_BIT

    # Viewport command is not really needed, but has been inserted for
    # Mac OSX. Presentation framework (Tk) does not send a reshape event,
    # when switching from one demo to another.
    glViewport 0 0 [$toglwin width] [$toglwin height]

    glColor3f 1.0 1.0 1.0
 
    glLoadIdentity
    glColor3f 1.0 1.0 1.0
    draw_triangle

    glEnable GL_LINE_STIPPLE
    glLineStipple 1 0xF0F0
    glLoadIdentity
    glTranslatef -20.0 0.0 0.0
    draw_triangle

    glLineStipple 1 0xF00F
    glLoadIdentity 
    glScalef 1.5 0.5 1.0
    draw_triangle
 
    glLineStipple 1 0x8888
    glLoadIdentity
    glRotatef 90.0 0.0 0.0 1.0
    draw_triangle
    glDisable GL_LINE_STIPPLE

    glFlush
    $toglwin swapbuffers
}

proc ReshapeCallback { toglwin { w -1 } { h -1 } } {
    set w [$toglwin width]
    set h [$toglwin height]

    glViewport 0 0 $w $h
    glMatrixMode GL_PROJECTION
    glLoadIdentity 
    if { $w <= $h } {
       glOrtho -50.0 50.0 \
               [expr -50.0*double($h)/double($w)] \
               [expr 50.0*double($h)/double($w)] \
                -1.0 1.0
    } else {
       glOrtho [expr -50.0*double($w)/double($h)] \
               [expr 50.0*double($w)/double($h)] \
               -50.0 50.0 -1.0 1.0
    }
    glMatrixMode GL_MODELVIEW
}

frame .fr
pack .fr -expand 1 -fill both
togl .fr.toglwin -width 500 -height 500 -double true \
                 -createcommand CreateCallback \
                 -reshapecommand ReshapeCallback \
                 -displaycommand DisplayCallback 
listbox .fr.usage -font $::listFont -height 1
label   .fr.info
grid .fr.toglwin -row 0 -column 0 -sticky news
grid .fr.usage   -row 1 -column 0 -sticky news
grid .fr.info    -row 2 -column 0 -sticky news
grid rowconfigure .fr 0 -weight 1
grid columnconfigure .fr 0 -weight 1
wm title . "Tcl3D demo: OpenGL Red Book example model"

bind . <Key-Escape> "exit"

.fr.usage insert end "Key-Escape Exit"
.fr.usage configure -state disabled

PrintInfo [tcl3dOglGetInfoString]
